TES IV OBLIVION MODDING

scn MidasAstralCombatShootScript
; - - NOT NPC Friendly

ref me
ref myBeam
float timer
float myX
float myY
float myZ
float fixZ
float myAngle
short doState
short index

; initial position vector
float xPos
float yPos
float zPos

; fly vector
float dx
float dy
float dz
float dt

; private
float ang
float xang
float yang
float zang
float x
float x2
float sin
float cos

Begin ScriptEffectStart

set me to GetSelf

if me == player && ( me.GetInCell BRMidasAstralPlane == 1 || me.GetInCell ArenaMatchCell == 1 )
Message "Вы не можете использовать это заклинание здесь.",1
return
endif

set ang to me.GetAngle z
set zang to ang
if ang > 180
set ang to (ang)-360
endif

set x to ang*0.0174532925
set x2 to x*x
set sin to x*(1-(x2/6)*(1-(x2/20)*(1-(x2/42)*(1-(x2/72)*(1-x2/110)))))
set cos to 1-0.5*x2*(1-(x2/12)*(1-(x2/30)*(1-(x2/56)*(1-x2/90))))
set dx to 10*sin
set dy to 10*cos

; vertical fly vector
set ang to me.GetAngle x
set xang to ang*cos ; uses settings from Horizontal Vector
set yang to -ang*sin

set x to -ang*0.0174532925
set x2 to x*x
set sin to x*(1-(x2/6)*(1-(x2/20)*(1-(x2/42)*(1-(x2/72)*(1-x2/110)))))
set cos to 1-0.5*x2*(1-(x2/12)*(1-(x2/30)*(1-(x2/56)*(1-x2/90))))
set dz to 10*sin

; initial position vector (to add to player coords)
set xPos to 5*dx*cos
set yPos to 5*dy*cos
set zPos to 100-25*(me.IsSneaking)+5*dz ; was 118

set MidasQuest.indexAstralCombat to ( MidasQuest.indexAstralCombat + 1 ) % 3
set index to MidasQuest.indexAstralCombat
if index == 0
set myBeam to MidasActivatorRayCyanRef01
elseif index == 1
set myBeam to MidasActivatorRayCyanRef02
else
set myBeam to MidasActivatorRayCyanRef03
endif

set myZ to me.Getpos Z
if me == player
MidasActivatorAstralRecallRef.moveto me 0 0 0
MidasActivatorAstralRecallRef.setpos z MyZ
endif

if myBeam != me && myBeam != 0
set MidasQuest.Proj to myBeam
myBeam.Activate me,1
myBeam.moveto me xpos ypos zpos
set myZ to myBeam.Getpos Z
myBeam.Setpos Z myZ
myBeam.SetAngle z zang
myBeam.SetAngle y yang
myBeam.SetAngle x xang
endif

;endif

end

scn MidasAstralCombatScript
; - - NPC Friendly (Behaves differently, only for special cases)

ref me
ref myHit
ref myUser
ref myParent
float timer
short doState
float myZ
float pZ
ref mytarget
short framecount

begin OnTriggerActor
set myHit to GetactionRef
if myTarget == 0 && doState == 1
if myHit.isActor
if myhit.getDead != 1&& myHit.isRidingHorse == 0 && myHit.isEssential == 0 && myHit != CreatureMehrunesDagon && myHit != myUser && myHit.GetInFaction MidasBossFaction == 0
set myTarget to myHit
if myUser == Player
set MidasQuest.AstralTarget to MyTarget
set myZ to myTarget.Getpos Z
MidasActivatorAstralCombatRef.Moveto MyTarget 0 0 0
set doState to 2
else
set myParent to MyUser.GetParentRef
set doState to 3
endif
Disable
endif
endif
endif
end

begin OnActivate
set me to GetSelf
set myUser to GetActionRef
if myUser == 0 || myUser.isActor == 0
set myUser to Player
endif
enable
Reset3DState
set timer to GetSecondsPassed
set timer to 0.0
set myTarget to 0
set doState to 0
end

begin gamemode

set timer to timer + GetSecondsPassed
set framecount to framecount + 1

if doState == 0 && timer > 0.2 && framecount > 2
set me to GetSelf
set myZ to me.getpos Z
playgroup forward 1
set doState to 1

; 1 skipped on purpose

elseif doState == 2 && timer > 0.35 ; Player Hit Target
if myTarget.isActor && myUser.GetInSameCell MyTarget
myTarget.PlayMagicShaderVisuals MidasEffectHoly 1
if myUser.GetInCell BRMidasAstralPlane != 1 || myUser.GetInCell ICArcaneUniversity
set doState to 4 ;IMPORTANT
myTarget.MoveToMarker MidasAstralCombatHeadingMarker
Disable
myUser.MoveToMarker MidasAstralCombatPlayerMarker
else
Message "Здесь это не работает.",1
set MidasQuest.AstralTarget to 0
endif
endif

elseif doState == 3 ; Non-Player User Hit Target
if myTarget.IsActor && myParent != 0 && myUser.GetInSameCell MyTarget
myTarget.PlayMagicShaderVisuals MidasEffectHoly 1
set doState to 4 ;IMPORTANT
myTarget.MoveToMarker MyParent
endif

endif

if Timer > 3.2 || doState == 4
Disable
set doState to 99
PositionCell -200 -300 -800 0 BRMidasCell
endif

end